[係統定時關機]winXP

[係統定時關機]winXP


有時候，我們需要定時關閉計算機，下麵筆者就介紹一個在Windows ＸＰ下實現定時關機的簡單方法
統在２２分鍾後自動關閉：點擊“開始→運行”，在“打開”中輸入命令“Ｓｈｕｔｄｏｗｎ －ｓ －ｔ １３２０”（注意：引號不輸入，
參數之間有空格，１３２０的單位是秒），
單擊“確定”按鈕即可。
指定係統在某個時間（比如１２：００）自動關閉：在“打開”中輸入命令“ａｔ １２：００ Ｓｈｕｔｄｏｗｎ －ｓ”即可。
取消定時關機：在“打開”中輸入命令“Ｓｈｕｔｄｏｗｎ －ａ”即可。
能的實現都是使用“Ｓｈｕｔｄｏｗｎ”命令實現的，ｓｈｕｔｄｏｗｎ的參數是在命令行窗口中輸入“ｓｈｕｔｄｏｗｎ”。筆者認為最有
用的是“－ｉ”參數，可以調出“遠程關機對話框”，能方便地實現局域網內計算機的遠程關機，有興趣的朋友可以試一試。

[係統定時關機]winXP自動關機命令---超實用

Windows XP的關機是由Shutdown.exe程序來控製的，位於Windows\System32文件夾中。如果想讓Windows 2000也實現同樣的效果，可以把
Shutdown.exe複製到係統目錄下。

比如你的電腦要在22:00關機，可以選擇"開始→運行"，輸入"at 22:00 Shutdown -s"，這樣，到了22點電腦就會出現"係統關機"對話框
，默認有30秒鍾的倒計時並提示你保存工作。如果你想以倒計時的方式關機，可以輸入"Shutdown.exe -s -t 3600"，
這裏表示60分鍾後自動關機，"3600"代表60分鍾。
設置好自動關機後，如果想取消的話，可以在運行中輸入"shutdown -a"。另外輸入"shutdown -i"，則可以打開設置自動關機對話框，
對自動關機進行設置。

Shutdown.exe的參數，每個都具有特定的用途，執行每一個都會產生不同的效果，比如"-s"就表示關閉本地計算機，"-a"表示取消關機操作，
下麵列出了更多參數，大家可以在Shutdown.exe中按需使用。

-f：強行關閉應用程序
　 -m：\\計算機名：控製遠程計算機
　　-i：顯示圖形用戶界麵，但必須是Shutdown的第一個選項
　　-l：注銷當前用戶
　　-r：關機並重啟
　　-t：時間：設置關機倒計時
　　-c："消息內容"：輸入關機對話框中的消息內容(不能超127個字符)



用這個試一下，不錯的。隻要把下麵的這段文字複製進記事本，在保存為.bat文件就可以運行了。

@ECHO off
TITLE greaterthanme-實現定時關機、注銷、重啟、鎖定等功能。
:start
CLS
COLOR 1f
rem 使用COLOR命令對控製台輸出顏色進行更改
MODE con: COLS=41 LINES=18
rem MODE語句為設定窗體的寬和高
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
ECHO %date% %tm1%點%tm2%分%tm3%秒
ECHO =========================================
ECHO 請選擇要進行的操作，然後按回車
ECHO ───────────────
ECHO.
ECHO 1. 定時關機
ECHO 2. 倒計時關機
ECHO 3. 刪除定時關機任務
ECHO 4. 查看任務狀態
ECHO 5. 刷新當前時間
ECHO 6. 重新啟動
ECHO 7. 鎖定計算機
ECHO 8. 注銷
ECHO 9. 退出
ECHO.
:cho
SET Choice=
SET /P Choice=選擇:
rem 設定變量"Choice"為用戶輸入的字符
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 如果輸入大於1位,取第1位,比如輸入132,則返回值為1
ECHO.
IF /I "%Choice%"=="1" GOTO SetHour
IF /I "%Choice%"=="2" GOTO outtime
IF /I "%Choice%"=="3" GOTO delAt
IF /I "%Choice%"=="4" GOTO view
IF /I "%Choice%"=="5" GOTO start
IF /I "%Choice%"=="6" GOTO restart
IF /I "%Choice%"=="7" GOTO lock
IF /I "%Choice%"=="8" GOTO logoff
IF /I "%Choice%"=="9" GOTO end
rem 為避免出現返回值為空或含空格而導致程序異常,需在變量外另加雙引號
rem 注意,IF語句需要雙等於號
rem 如果輸入的字符不是以上數字,將返回重新輸入
ECHO 選擇無效，請重新輸入
ECHO.
GOTO cho
:SetHour
CLS
ECHO.
SET ask=
SET /p ask=是否設定為每天執行關機命令(y/n):
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="y" GOTO yes
IF /I "%ask%"=="n" GOTO no
GOTO SetHour
:yes
ECHO 請指定24小時製式時間,格式為 小時:分鍾
SET shutdowntime=
SET /p shutdowntime=輸入:
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul
rem 設定為每周的星期一至星期日,即為每天
IF NOT errorlevel 1 GOTO ok
rem 如果輸入正確,就執行ok段的語句
ECHO %shutdowntime% 不是標準的時間格式,請重新輸入
ECHO.
GOTO yes
:no
ECHO 請指定24小時製式時間,格式為 小時:分鍾
SET shutdowntime=
SET /p shutdowntime=輸入:
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF NOT errorlevel 1 GOTO ok
ECHO %shutdowntime% 不是標準的時間格式,請重新輸入
ECHO.
GOTO no
:ok
ECHO.
SET h=%shutdowntime:~1,1%
SET ah=%shutdowntime:~0,1%
SET am=%shutdowntime:~2,2%
SET bh=%shutdowntime:~0,2%
SET bm=%shutdowntime:~3,2%
IF "%h%"==":" (
SET HM=%ah%時%am%分
) ELSE (
SET HM=%bh%時%bm%分)
rem 如果輸入h:mm則HM=h時mm分,否則HM=hh時mm分
IF /I "%ask%"=="y" ECHO 係統將於每天的%HM%關閉
IF /I "%ask%"=="n" ECHO 係統將於%HM%關閉
ECHO 設定完畢! 按任意鍵繼續...
PAUSE >nul
GOTO start
:outtime
CLS
ECHO.
ECHO 請輸入倒計時秒數
ECHO ────────
ECHO (設定後要取消,單擊"確定"後按Ctrl+C鍵兩次)
SET timed=
SET /p timed=輸入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 GOTO ok
ECHO %timed% 是無效的關機時間,請重新輸入
ECHO.
GOTO outtime
:delAt
cls
echo.
at /del /y
echo 定時關機任務已取消,按任意鍵繼續...
pause >nul
GOTO start
:view
MODE con: COLS=85 LINES=18
COLOR 70
ECHO.
at
ECHO 按任意鍵繼續...
PAUSE >nul
GOTO start
:restart
shutdown -r -t 0
:lock
rundll32.exe user32.dll,LockWorkStation
goto start
:logoff
logoff
:end
exit
效果不錯的。